COMMENT ⊗   VALID 00003 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	ENTRY COMPLI
C00003 00003	BEGIN "COMPLI"
C00004 ENDMK
C⊗;
ENTRY COMPLI;
COMMENT*****************************************************

            COMPLI

        J. A. NUGENT  2/14/71


COMPLI IS FUNCTION TO COMPLIMENT A GREY SCALE PICTURE, THAT IS MAKE A
PHOTOGRAPHIC  NEGATIVE  OUT  OF  IT.      ANY POINT VALUE(I,J) YIELDS
2↑BYTSZ-1 - VALUE(I,J)

NOTE:  THIS  FUNCTION  IS PARTICULARLY USEFUL FOR CONVERTING STANFORD
PICTURES TO CMU FORMAT.

 *************************************************************;
BEGIN "COMPLI"
REQUIRE "BUFDEC.SAI" SOURCE!FILE;
INTERNAL SIMPLE INTEGER PROCEDURE COMPLI(INTEGER INBUF);
 BEGIN "COMPLI"

   INTEGER IT,I,J,ISTOP,JSTOP,PTR1,PTR2,OUTBUF,BYT;

    IT←2↑(BYT←BYTSZ(INBUF))-1;
    ISTOP←ROWS(INBUF);
    JSTOP←COLMS(INBUF);
    GETBUF(ISTOP,JSTOP,BYT,OUTBUF←FNDBUF);
    PUTSUB(ISUBST(INBUF),JSUBST(INBUF),OUTBUF);
   
    FOR I←1 THRU ISTOP DO
	BEGIN
	PTR1←INPTR(I,1,INBUF);
	PTR2←OUTPTR(I,1,OUTBUF);
	FOR J←1 THRU JSTOP DO
	    IDPB(IT-ILDB(PTR1),PTR2);
	END;

    RETURN(OUTBUF);
 END "COMPLI";
END "COMPLI";